Add vim interview plugin

1 files changed, 49 insertions, 0 deletions

diff --git a/.vim/ftplugin/interview.vim b/.vim/ftplugin/interview.vim
new file mode 100644
index 0000000..8b70e70
--- /dev/null
+++ b/.vim/ftplugin/interview.vim
@@ -0,0 +1,49 @@
+" InterviewTimestamp inserts a timestamp into an interview file. The timestamp
+" is the current HH:MM in 24-hour time and an elapsed time in either seconds
+" or minutes from the prior timestamp.
+function InterviewTimestamp()
+    if !exists("*strptime")
+        echoerr 'Platform has no strptime! InterviewTimestamp will not work.'
+        return
+    end
+
+    " Insert a blank line if the current line is non-empty
+    let l:line = line('.')
+    if getline(l:line) !~ '^$'
+        call append(l:line, '')
+        let l:line = l:line + 1
+    endif
+
+    let l:elapsed = '0s'
+    let l:nowstr = strftime('%H:%M:%S')
+
+    " Seems pointless to re-parse these but in the absence of a date the
+    " timestamps are only relative to each other so we can't use localtime. We
+    " also can't assume that we have any other context than what exists in the
+    " file.
+    let l:nowtime = strptime('%H:%M:%S', l:nowstr)
+
+    " Find a previous timestamp if one exists and calculate min/sec elapsed
+    let l:prev = search('^#ts ', 'bW')
+    if l:prev > 0
+        let l:parts = split(getline(l:prev))
+        let l:prevtime = strptime('%H:%M:%S', l:parts[1])
+
+        let l:elapsed = l:nowtime - l:prevtime
+        if l:elapsed > 60
+            let l:elapsed = l:elapsed / 60 . 'm'
+        else
+            let l:elapsed = l:elapsed . 's'
+        endif
+    endif
+
+    " Insert the timestamp, add a blank line, and move the cursor to that
+    " line. Assumes we're in insert mode already so the user is ready to type
+    call append(l:line, '#ts ' . l:nowstr . ' ' . l:elapsed)
+    call append(l:line + 1, '')
+    call cursor(l:line + 2, 1)
+endfunction
+
+inoremap <buffer> <silent> <leader><enter> <C-O>:call InterviewTimestamp()<CR>
+inoremap <buffer> <leader>t TC:<space>
+inoremap <buffer> <leader>m ME:<space>